mirror of
https://github.com/CLIUtils/CLI11.git
synced 2025-04-30 12:43:52 +00:00
79a1847605
* Overflowing an integer conversion now results in a conversion failure * CMake improvements for VERSION and inital packing support * Fix for recent addition of overflow check * Conan file now gets version from Version.hpp file too
83 lines
2.4 KiB
CMake
83 lines
2.4 KiB
CMake
#
|
|
#
|
|
# Downloads GTest and provides a helper macro to add tests. Add make check, as well, which
|
|
# gives output on failed tests without having to set an environment variable.
|
|
#
|
|
#
|
|
set(UPDATE_DISCONNECTED_IF_AVAILABLE "UPDATE_DISCONNECTED 1")
|
|
|
|
include(DownloadProject)
|
|
download_project(PROJ googletest
|
|
GIT_REPOSITORY https://github.com/google/googletest.git
|
|
GIT_TAG release-1.8.0
|
|
UPDATE_DISCONNECTED 1
|
|
QUIET
|
|
)
|
|
|
|
set(gtest_force_shared_crt ON CACHE BOOL "" FORCE)
|
|
|
|
# CMake warning suppression will not be needed in version 1.9
|
|
set(CMAKE_SUPPRESS_DEVELOPER_WARNINGS 1 CACHE BOOL "")
|
|
add_subdirectory(${googletest_SOURCE_DIR} ${googletest_SOURCE_DIR} EXCLUDE_FROM_ALL)
|
|
unset(CMAKE_SUPPRESS_DEVELOPER_WARNINGS)
|
|
|
|
if (CMAKE_CONFIGURATION_TYPES)
|
|
add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND}
|
|
--force-new-ctest-process --output-on-failure
|
|
--build-config "$<CONFIGURATION>")
|
|
else()
|
|
add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND}
|
|
--force-new-ctest-process --output-on-failure)
|
|
endif()
|
|
set_target_properties(check PROPERTIES FOLDER "Scripts")
|
|
|
|
#include_directories(${gtest_SOURCE_DIR}/include)
|
|
|
|
# More modern way to do the last line, less messy but needs newish CMake:
|
|
# target_include_directories(gtest INTERFACE ${gtest_SOURCE_DIR}/include)
|
|
|
|
|
|
if(GOOGLE_TEST_INDIVIDUAL)
|
|
if(NOT CMAKE_VERSION VERSION_LESS 3.9)
|
|
include(GoogleTest)
|
|
else()
|
|
set(GOOGLE_TEST_INDIVIDUAL OFF)
|
|
endif()
|
|
endif()
|
|
|
|
# Target must already exist
|
|
macro(add_gtest TESTNAME)
|
|
target_link_libraries(${TESTNAME} PUBLIC gtest gmock gtest_main)
|
|
|
|
if(GOOGLE_TEST_INDIVIDUAL)
|
|
if(CMAKE_VERSION VERSION_LESS 3.10)
|
|
gtest_add_tests(TARGET ${TESTNAME}
|
|
TEST_PREFIX "${TESTNAME}."
|
|
TEST_LIST TmpTestList)
|
|
else()
|
|
gtest_discover_tests(${TESTNAME}
|
|
TEST_PREFIX "${TESTNAME}."
|
|
)
|
|
|
|
endif()
|
|
else()
|
|
add_test(${TESTNAME} ${TESTNAME})
|
|
endif()
|
|
set_target_properties(${TESTNAME} PROPERTIES FOLDER "Tests")
|
|
|
|
endmacro()
|
|
|
|
mark_as_advanced(
|
|
gmock_build_tests
|
|
gtest_build_samples
|
|
gtest_build_tests
|
|
gtest_disable_pthreads
|
|
gtest_force_shared_crt
|
|
gtest_hide_internal_symbols
|
|
BUILD_GMOCK
|
|
BUILD_GTEST
|
|
)
|
|
|
|
set_target_properties(gtest gtest_main gmock gmock_main
|
|
PROPERTIES FOLDER "Extern")
|